"Datei öffnen" Dialog

Posted by Excel Community on 5. September 2024 at 12:42

Hier ist die Vorlage die in ein Modul eingefügt werden muss.

m_SelectedFilePath As String ' Modul-Variable für den Dateipfad
'
Sub RequestFilePath()
    ' Pfad über die Funktion GetFilePath anfordern
    m_SelectedFilePath = GetFilePath()
    ' Prüfen, ob ein Pfad zurückgegeben wurde
    If m_SelectedFilePath <> "" Then
        MsgBox "Ausgewählter Dateipfad: " & m_SelectedFilePath
    Else
        MsgBox "Keine Datei ausgewählt."
    End If
End Sub

Function GetFilePath(Optional startPath As String = "C:\") As String

    Dim fDialog As Office.FileDialog
    Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
    With fDialog
        .Title = "Datei auswählen"             ' Fenstertitel
        .AllowMultiSelect = False              ' Nur eine Datei auswählbar
        .ButtonName = "Auswählen"              ' Button Beschriftung
        .Filters.Clear                         ' Alle Filter löschen
        .Filters.Add "Excel-Dateien", "*.xl*"  ' Eigene Filter anlegen
        .Filters.Add "Word-Dateien", "*.do*"
        .Filters.Add "Access-Dateien", "*.mdb; *.accdb"
        .FilterIndex = 2                       ' Vorselektierter Filter
        .InitialFileName = startPath           ' Startverzeichnis, standardmäßig "C:\"
        .InitialView = msoFileDialogViewDetails ' Ansicht im Detailmodus
        If .Show = -1 Then                     ' Dialog anzeigen und prüfen, ob OK geklickt wurde
            GetFilePath = .SelectedItems(1)    ' Rückgabe des ausgewählten Pfads
        Else
            GetFilePath = ""                   ' Wenn Abbrechen gedrückt wird, leerer String
        End If
    End With
    Set fDialog = Nothing
End Function

Excel Community replied 7 months aktiv. 1 Member · 0 Replies

0 Replies

Sorry, there were no replies found.